Integración múltiple con MAPLE V (IV)

Aplicaciones de las integrales dobles y triples

Inicialización

> restart:

> with( plots ): # librería para trazado de gráficas

> setoptions( thickness=1, font=[TIMES,ROMAN,12], axesfont=[TIMES,ROMAN,8], titlefont=[TIMES,ITALIC,14] );

> setoptions3d( thickness=1, font=[TIMES,ROMAN,12], axesfont=[TIMES,ROMAN,8], titlefont=[TIMES,ITALIC,14], axes=NORMAL );

> with( linalg ): # librería de álgebra lineal (-> Jacobiano)

> with( student ): # librería para cálculo de una variable

> read( "a:calcplot2.txt" ): # librería para cálculo de varias variables (especificar adecuadamente la ruta del directorio donde se encuentra, si no es el mismo de la práctica)

Warning, new definition for norm

Warning, new definition for trace

>

Masa y centro de masa de un sólido

Ejercicio.- Encontrar la masa del sólido limitado por el cilindro y el cono con densidad .

Solución

La masa viene dada por una integral triple. La frecuente aparición de la expresión refleja la existencia de simetría axial respecto del eje OZ y sugiere el uso de coordenadas cilíndricas para el cálculo de dicha integral..

La "tapa" del sólido está formada por la porción del cono que queda por encima del plano OXY : , mientras que el "fondo" del mismo está formada por la porción de cono que queda por debajo del plano OXY : . La proyección del cilindro sobre el plano OXY es su sección circular. La ecuación en polares de esta proyección es , que corresponde a una circunferencia centrada en (1,0) de radio 1 en el plano OXY . La determinación del ángulo debe ser tomada en el intervalo , para garantizar que el radio es siempre positivo.

Así pues, las secciones circulares del cilindro pueden ser descritas en polares como sigue:

> drdtplot( r=0..2*cos(theta), theta = -Pi/2 .. Pi/2 );

>

Obtenemos el sólido al añadir la tercera dimensión, teniendo en cuenta que su "tapa" y su "fondo" vienen determinados por el cono:

> dzdrdtplot( z=-r..r, r=0..2*cos(theta), theta=-Pi/2..Pi/2 );

>

La densidad es:

> rho := r;

>

Por tanto, la masa viene dada por la integral triple siguiente, en cuyo integrando aparece incorporado el jacobiano para coordenadas cilíndricas:

> M := Int( Int( Int( rho * r, z = -r .. r ), r = 0 .. 2*cos(theta) ), theta = -Pi/2 .. Pi/2 );

>

Las dos primeras integrales se calculan sin dificultad. Para la tercera (en ), que supone integrar , puedes consultar una tabla, auxiliarte de la función Beta... ¡o pedirle a MAPLE que la resuelva por ti!. En cualquier caso, se obtiene finalmente:

> M := value( M );

>

Observa que por simetría podríamos haber simplificado los cálculos.

Aunque el problema no pide el centro de masa, es posible obtener esta información casi sin esfuerzo adicional. Razones de simetría (mira la gráfica) sugieren que el centro de masa debe estar sobre los planos y . La tercera coordenada del centro de masa debe quedar por debajo de ; para calcularla basta con evaluar otra integral triple:

> xbarra := Int( Int( Int( (r*cos(theta)) * rho * r, z = -r .. r ), r = 0 .. 2*cos(theta) ), theta = -Pi/2 .. Pi/2 )/M ;

>

> xbarra := value( xbarra );

>

Comprobemos que las integrales correspondientes a las otras dos coordenadas del centro de masa tienen el valor esperado:

> ybarra := Int( Int( Int( (r*sin(theta)) * rho * r, z = -r .. r ), r = 0 .. 2*cos(theta) ), theta = -Pi/2 .. Pi/2 ) / M ;

>

> ybarra := value( ybarra );

>

> zbarra := Int( Int( Int( z * rho * r, z = -r .. r ), r = 0 .. 2*cos(theta) ), theta = -Pi/2 .. Pi/2 ) / M ;

>

> zbarra := value( zbarra );

>

Se concluye que el centro de masa es ( 4/3, 0, 0 ).